Can I extract unique cell values from every nth column?

I have a range that covers B5:XA160.  For each row, data is entered in
11-cell groups: date, some numbers, description (a text value), more
numbers, and more numbers.  At first it was enough to merely count how
many times certain descriptions appeared, because those were the only
ones we would see - or so the story went.  Now, I need to extract the
unique descriptions AND provide a count!

Actually, I'm cheating a bit.  I'm using SUMPRODUCT to return the
number of times the expected descriptions appear, and by subtracting
these from the total number of text values I get a count of "Other".

Desc1: =SUMPRODUCT(--(ISNUMBER(SEARCH("Desc1",B5:XA5))))
   (This one only searches the top row because the value is repeated
all the way down.)

Desc2: =SUMPRODUCT(--(ISNUMBER(SEARCH("Desc2",$B$5:$XA$160))))
   (This one searches the whole range.)

Other: =(SUMPRODUCT(ISTEXT($B$5:$XA$160)*1))-((SUMPRODUCT(--(ISNUMBER
(SEARCH("Desc1",$B$5:$XA$160)))))+(SUMPRODUCT(--(ISNUMBER(SEARCH
("Desc2",$B$5:$XA$160))))))
   (This one searches the whole range for all text values, then
subtracts the known values.)

Now, though, I need to show what these "Other" values are and provide
a count.  Is that possible without building an array in VBA?

Ed
0
prof_ofwhat (194)
1/26/2009 7:28:49 PM
excel 39879 articles. 2 followers. Follow

9 Replies
995 Views

Similar Articles

[PageSpeed] 21

Hi,

Try something like this:
=SUMPRODUCT(1/COUNTIF(Range,Range))
for counting uniques 

To get a list of uniques use Data, Filter, Advanced Filter, Unique Records
-- 
If this helps, please click the Yes button

Cheers,
Shane Devenshire


"Ed from AZ" wrote:

> I have a range that covers B5:XA160.  For each row, data is entered in
> 11-cell groups: date, some numbers, description (a text value), more
> numbers, and more numbers.  At first it was enough to merely count how
> many times certain descriptions appeared, because those were the only
> ones we would see - or so the story went.  Now, I need to extract the
> unique descriptions AND provide a count!
> 
> Actually, I'm cheating a bit.  I'm using SUMPRODUCT to return the
> number of times the expected descriptions appear, and by subtracting
> these from the total number of text values I get a count of "Other".
> 
> Desc1: =SUMPRODUCT(--(ISNUMBER(SEARCH("Desc1",B5:XA5))))
>    (This one only searches the top row because the value is repeated
> all the way down.)
> 
> Desc2: =SUMPRODUCT(--(ISNUMBER(SEARCH("Desc2",$B$5:$XA$160))))
>    (This one searches the whole range.)
> 
> Other: =(SUMPRODUCT(ISTEXT($B$5:$XA$160)*1))-((SUMPRODUCT(--(ISNUMBER
> (SEARCH("Desc1",$B$5:$XA$160)))))+(SUMPRODUCT(--(ISNUMBER(SEARCH
> ("Desc2",$B$5:$XA$160))))))
>    (This one searches the whole range for all text values, then
> subtracts the known values.)
> 
> Now, though, I need to show what these "Other" values are and provide
> a count.  Is that possible without building an array in VBA?
> 
> Ed
> 
0
1/27/2009 12:24:00 AM
Hi, Shane.  Thanks for the response.

> To get a list of uniques use Data, Filter, Advanced Filter, Unique Record=
s

This won't work - I need a formula that will return unique records -
if that is possible, that is.  I need to keep a running summary on
several different sheets in one workbook, and I need to pass this off
to people who need the data.  They are not going to filter for their
data - they expect me to have it summarized (else why are they paying
me??).  And I'd like to get away from having to manually filter and
enter every time they call for the summary data.

I'd also like to stay away from any kind of code in the workbook -
many computers are set up to either refuse code to run or even reject
an email with a coded attachment.

If this can't be put into a formula, then I guess I'll have to stay
manual.

Ed


On Jan 26, 5:24=A0pm, Shane Devenshire
<ShaneDevensh...@discussions.microsoft.com> wrote:
> Hi,
>
> Try something like this:
> =3DSUMPRODUCT(1/COUNTIF(Range,Range))
> for counting uniques
>
> To get a list of uniques use Data, Filter, Advanced Filter, Unique Record=
s
> --
> If this helps, please click the Yes button
>
> Cheers,
> Shane Devenshire
>
>
>
> "Ed from AZ" wrote:
> > I have a range that covers B5:XA160. =A0For each row, data is entered i=
n
> > 11-cell groups: date, some numbers, description (a text value), more
> > numbers, and more numbers. =A0At first it was enough to merely count ho=
w
> > many times certain descriptions appeared, because those were the only
> > ones we would see - or so the story went. =A0Now, I need to extract the
> > unique descriptions AND provide a count!
>
> > Actually, I'm cheating a bit. =A0I'm using SUMPRODUCT to return the
> > number of times the expected descriptions appear, and by subtracting
> > these from the total number of text values I get a count of "Other".
>
> > Desc1: =3DSUMPRODUCT(--(ISNUMBER(SEARCH("Desc1",B5:XA5))))
> > =A0 =A0(This one only searches the top row because the value is repeate=
d
> > all the way down.)
>
> > Desc2: =3DSUMPRODUCT(--(ISNUMBER(SEARCH("Desc2",$B$5:$XA$160))))
> > =A0 =A0(This one searches the whole range.)
>
> > Other: =3D(SUMPRODUCT(ISTEXT($B$5:$XA$160)*1))-((SUMPRODUCT(--(ISNUMBER
> > (SEARCH("Desc1",$B$5:$XA$160)))))+(SUMPRODUCT(--(ISNUMBER(SEARCH
> > ("Desc2",$B$5:$XA$160))))))
> > =A0 =A0(This one searches the whole range for all text values, then
> > subtracts the known values.)
>
> > Now, though, I need to show what these "Other" values are and provide
> > a count. =A0Is that possible without building an array in VBA?
>
> > Ed- Hide quoted text -
>
> - Show quoted text -

0
prof_ofwhat (194)
1/27/2009 1:47:57 PM
> .. a range that covers B5:XA160
> .. need to extract the unique descriptions AND provide a count

Here's an example of a pure formulas set up (uses 3 cols) that will 
dynamically extract uniques from a multi-col source range and output into a 
single col. It might appeal to you.

Assume a source range with anchor cell B5 and 3 cols, eg: B5:D10

In F1:
=OFFSET($B$5,INT((ROWS($1:1)-1)/3),MOD(ROWS($1:1)-1,3))
Copy F1 down to extract the multi-col source range into a single col. Copy 
down to F18* to cover the full extent of the source data matrix
*B5:D10 has 6 rows x 3 cols = 18 cells

Adapt the anchor cell B5 and the "3" in the INT and MOD parts (3 = # of 
source cols) to suit your actual source range, eg: B5:XA160? I don't have 
xl07 (max col in xl03 is only col IV), but it should work just as well in 
your xl07.

Then
In G1: =IF(F1=0,"",IF(COUNTIF(F$1:F1,F1)>1,"",ROW()))
In H1: =IF(ROW()>COUNT(G:G),"",INDEX(F:F,SMALL(G:G,ROW())))
Copy G1:H1 down to the extent in col F. Minimize cols F & G. Col H will 
return the required uniques list, all neatly bunched at the top.

And if you need the count of the uniques extracted into col H,
just use in say I1: =COUNT(H:H)

Adapt to suit ..
-- 
Max
Singapore
http://savefile.com/projects/236895
Downloads:22,500 Files:370 Subscribers:66
xdemechanik
---  


0
demechanik (4694)
1/28/2009 12:14:03 AM
Correction to this part:
> And if you need the count of the uniques extracted into col H,
> just use in say I1: =COUNT(H:H)

Use something like this to count the uniques in col H:
=SUMPRODUCT(--(H1:H1000<>""))
-- 
Max
Singapore
http://savefile.com/projects/236895
Downloads:22,500 Files:370 Subscribers:66
xdemechanik
---  


0
demechanik (4694)
1/28/2009 12:55:44 AM
Max, this is absolutely awesome!!

I seem to have done smoething wrong, though.  Here's how mine looks:

I used a range from B5:AH160, which is 33 cols x 156 rows =3D 5148
cells.  I started all these formulas in row 166.
-- I numbered 1, 2, 3 ... 5148 in H166:H5313.
-- In I166, I put =3DOFFSET($B$5,INT((ROWS($1:1)-1)/33),MOD(ROWS
($1:1)-1,33)) and ran that down.  It gave me everything in my range
down a single column.
-- Because I only need unique text values, and everything else is a
number or a date, I put =3DIF(ISTEXT(I166),I166,"") in J166 and ran it
down.  It gave me just text values in J with everything else blank.
-- In K166, I put =3DIF(J166=3D"","",IF(COUNTIF(J$166:J166,J166)>1,"",ROW
())).  This gave me the row number of the first occasion of each text
value in J.

So far, so good!  In fact, just screamin' excellent!!!  Then . . .

-- In L166, I put =3DIF(ROW()>COUNT(K166:K5313),"",INDEX(J166:J5313,SMALL
(K166:K5313,ROW()))).  I get nothing but blank cells.  I also tried =3DIF
(ROW()>COUNT(K166:K5313),"",INDEX(I166:I5313,SMALL(K166:K5313,ROW())))
- also blank cells.

Did I mess it up by putting in that extra column for only text values?

Ed


On Jan 27, 5:55=A0pm, "Max" <demecha...@yahoo.com> wrote:
> Correction to this part:
>
> > And if you need the count of the uniques extracted into col H,
> > just use in say I1: =3DCOUNT(H:H)
>
> Use something like this to count the uniques in col H:
> =3DSUMPRODUCT(--(H1:H1000<>""))
> --
> Max
> Singaporehttp://savefile.com/projects/236895
> Downloads:22,500 Files:370 Subscribers:66
> xdemechanik
> --- =A0

0
prof_ofwhat (194)
1/28/2009 2:31:25 PM
These 2 slight adjustments to J166 and L166
should drive it out correctly for you, Ed

In J166, copied down:
=IF(J166="","",IF(COUNTIF(J$166:J166,J166)>1,"",ROWS($1:1)))

In L166, copied down:
=IF(ROWS($1:1)>COUNT(K$166:K$5313),"",INDEX($J$166:$J$5313,SMALL(K$166:K$5313,ROWS($1:1))))

Basically, replace ROW() with ROWS($1:1)
and fix the ranges: K$166:K$5313, $J$166:$J$5313

ROWS($1:1) enables an easier to cross-relate flagging/reading between the 
criteria/extract cols since it'll always start with: 1 irrespective of where 
it's placed in (unlike ROW() which is sensitive), while the explicit ranges 
now need to be fixed for copying down (unlike the earlier, neater looking 
entire col ranges which doesn't need to be).
-- 
Max
Singapore
http://savefile.com/projects/236895
Downloads:22,500 Files:370 Subscribers:66
xdemechanik
--- 
"Ed from AZ" <prof_ofwhat@yahoo.com> wrote in message 
news:d507af82-bed3-4327-bbc8-4591546c3977@a39g2000prl.googlegroups.com...
Max, this is absolutely awesome!!

I seem to have done something wrong, though.  Here's how mine looks:

I used a range from B5:AH160, which is 33 cols x 156 rows = 5148
cells.  I started all these formulas in row 166.
-- I numbered 1, 2, 3 ... 5148 in H166:H5313.
-- In I166, I put =OFFSET($B$5,INT((ROWS($1:1)-1)/33),MOD(ROWS
($1:1)-1,33)) and ran that down.  It gave me everything in my range
down a single column.
-- Because I only need unique text values, and everything else is a
number or a date, I put =IF(ISTEXT(I166),I166,"") in J166 and ran it
down.  It gave me just text values in J with everything else blank.
-- In K166, I put =IF(J166="","",IF(COUNTIF(J$166:J166,J166)>1,"",ROW
())).  This gave me the row number of the first occasion of each text
value in J.

So far, so good!  In fact, just screamin' excellent!!!  Then . . .

-- In L166, I put =IF(ROW()>COUNT(K166:K5313),"",INDEX(J166:J5313,SMALL
(K166:K5313,ROW()))).  I get nothing but blank cells.  I also tried =IF
(ROW()>COUNT(K166:K5313),"",INDEX(I166:I5313,SMALL(K166:K5313,ROW())))
- also blank cells.

Did I mess it up by putting in that extra column for only text values?

Ed 


0
demechanik (4694)
1/28/2009 11:07:52 PM
Oops, typo: "In J166" should read "In K166" in the earlier, viz.:

In K166, copied down:
=IF(J166="","",IF(COUNTIF(J$166:J166,J166)>1,"",ROWS($1:1)))
-- 
Max
Singapore
http://savefile.com/projects/236895
Downloads:22,500 Files:370 Subscribers:66
xdemechanik
---  


0
demechanik (4694)
1/28/2009 11:25:22 PM
Max:

Sorry to keep you hanging on this.  I was out for a few days and got
caught palying catch-up.  This does indeed do everything I hoped for.
Thank you so much.  When I have time, I want to go back and more
closely examine what you did so I can better understand what's
happening - but for right now it's just great that it works!

Again, many thanks.
Ed


On Jan 28, 4:25=A0pm, "Max" <demecha...@yahoo.com> wrote:
> Oops, typo: "In J166" should read "In K166" in the earlier, viz.:
>
> In K166, copied down:
> =3DIF(J166=3D"","",IF(COUNTIF(J$166:J166,J166)>1,"",ROWS($1:1)))
> --
> Max
> Singaporehttp://savefile.com/projects/236895
> Downloads:22,500 Files:370 Subscribers:66
> xdemechanik
> --- =A0

0
prof_ofwhat (194)
2/4/2009 1:53:40 PM
Good to hear, thanks for closing off here.
-- 
Max
Singapore
http://savefile.com/projects/236895
Downloads:22,500 Files:370 Subscribers:66
xdemechanik
--- 
"Ed from AZ" <prof_ofwhat@yahoo.com> wrote in message 
news:513a8ef3-892e-4311-a3c6-be282ab6ef90@i20g2000prf.googlegroups.com...
Max:

Sorry to keep you hanging on this.  I was out for a few days and got
caught palying catch-up.  This does indeed do everything I hoped for.
Thank you so much.  When I have time, I want to go back and more
closely examine what you did so I can better understand what's
happening - but for right now it's just great that it works!

Again, many thanks.
Ed


0
demechanik (4694)
2/4/2009 2:00:54 PM
Reply:

Similar Artilces:

Newbie: counting repeated values ???????
Hello all, I know little about Excel that's why i am posting this message here. I have a sheet with several columns, one of those columns have always one of this 2 values: YES or NO My question is, is there a way to count how many YES or NO are in that column and display the number in other cell? I already tried =+COUNTIF(D10:D240,"Yes") but i get a msg saying my form have an error. Thanks in advance, Helder Portugal Helder Take the + sign out of your formula =COUNTIF(C3:C8,"Yes") >-----Original Message----- >Hello all, > >I know little about Excel...

Can't see 401(k) contribiltion total
I've set up a 401(k)accont. I transfer contribiltions to this 401(k)account from each paycheck. When I go to the 401 (k) account view, it shows all the informations such as transections and the account vallue ect., EXCEPT the total contribiltion. I want to know not only what my 401(k) vallue is, but how much money I have contribilt total or over a period of time as well. I find no place to see it. Anybody can help? I'm using Money2002 and 2004 Trial Verstion. Thanks a lot! ...

How can I print a selection in Outlook 2003?
How can I print just a selection of an email in Outlook 2003? The printer driver window is different from the one that comes up in Outlook Express. Thank you! You can do this for HTML formatted messages. Highlight your text, File-> Print... and select to print only the selection -- Robert Sparnaaij [MVP-Outlook] www.howto-outlook.com Tips of the month: -What do the Outlook Icons Mean? -Create an Office 2003 CD slipstreamed with Service Pack 1 ----- "Murphie" <Murphie@discussions.microsoft.com> wrote in message news:92F39B50-B877-408A-AAA7-DF350B1D72ED@microsoft.com....

How to Link to the next blank row after the last entry in a column?
Cell BM6 Sheet1, has a formula that gives me a numeric total. The total belongs in Column D1 Sheet2 after the last entry, and there will be cells that will remain blank in that column before the last entry. Sheet1 is a work sheet, which will be saved with a new file name at the end of the month after the totals have been sent to Sheet2. Sheet2 is a permanent, ongoing record. The numbers on original Sheet1 will then be erased and the worksheet reused for the new month. :confused: How do I get the values into the appropriate row of Sheet2 and have them remain there when I reuse the workshee...

error: OBE-15502 Can only have 16000 per document
Hi, I tried to export data from oracle query builder to Excel sheet, got a error message: OBE-15502 Can only have 16000 per document Is there any way i can get more records(over 16000 or unlimited) in one sheet? thanks. -- JJ ...

Can different editions of Publisher be used together?
If my son uses Publisher 2003 on a school computer, downloads his work to a flash drive, brings it home to edit on Publisher 2007, will he then be able to take the edited work back to the school computer to be used, or will it not be compatible? Stateparent wrote: > If my son uses Publisher 2003 on a school computer, downloads his work to a > flash drive, brings it home to edit on Publisher 2007, will he then be able > to take the edited work back to the school computer to be used, or will it > not be compatible? Publisher 2003 and 2007 share a common file format, so the sc...

How do I make a column of checkboxes quickly?
I have a list of people my company has already mailed letters to (about 500) .. I have another separate list of people that may or may not have been mailed to from the first list. Is there a way to quickly creat a column of checkboxes and then somehow crossreference these people that have already been mailed to (both list have account numbers) so that we can exclude them from our next mail out? See http://tinyurl.com/bfkdt -- HTH Bob Phillips "Kevin Kimbrell via OfficeKB.com" <forum@nospam.OfficeKB.com> wrote in message news:eaaf5760ccae43ac8b829a58e9708b6b@OfficeKB.com....

Can't send/receive
anyone have a situation where all of sudden they can't send new messages or receive anything? I get a message when I click on "accounts" that says 'fatal error in outlook unable to complete operation" ...

Can not Customize Leads View
Hi I have tried to customize the Leads view, I tried to add a view and add some columns to it. The view is shown however I see only the name column. When I go back to the View customization, I see the columns I added. Published your customizations??? -- ---------------------- regards, Ilya Milshtein MBS Master, MBSCP, MCP Softline International www.softline.ru "alsap" wrote: > Hi I have tried to customize the Leads view, I tried to add a view and add > some columns to it. > The view is shown however I see only the name column. > When I go back to the View customi...

Can I change the "Applied Task Update Requests and Errors" view?
I really like this view in PWA 2007, but I would like to replace one column with another. Is this view customizeable? Randy -- Bad news, my friend. This view is not customizable, nor is the view shown in the Task Updates customizable (which many users wish it was). Hope this help. -- Dale A. Howard [MVP] VP of Educational Services msProjectExperts http://www.msprojectexperts.com http://www.projectserverexperts.com "We write the books on Project Server" "Randy Schmid" <RandySchmid@discussions.microsoft.com> wrote in message news:72FA34B5-...

Hyperlink value crashes Access
If I assign a hyperlink value to a cmd button or in code using the follow hyperlink method, using a link value like http://www.cookbookplus.com/Activate.aspx, the page is accessed [Internet Explorer] OK, but the Access app crashes every time. However, if I instead just target the main web site http://www.cookbookplus.com that page is opened AND Access does not crash. Crashes also occur if a hyperlink field is populated with http://www.cookbookplus.com/Activate.aspx Again, that page is opened in IE, but Access crashes. The targeted page is a simple, safe, publicly available...

Should be an easy but I can not figure it out!!
I have a text box where the user enters a date and it is assigned to variable txtDate. How to I convert that to the serial number of the date? Thanks for the help IIRC, you can use DATEVAL(String) to get the serial date. -- HTH, Barb Reinhardt "VinceW" wrote: > I have a text box where the user enters a date and it is assigned to variable > txtDate. How to I convert that to the serial number of the date? > > Thanks for the help Barb, Thanks for the quick reply, however I get the error "Sub or Function not defined" when trying...

Bulk attachments
I have a very long list of Images in a single folder that I want to attach to seperate fields in a table/form. Each record contains two images, which are named like this: W:\Foldername\Micromap Run 001 A.bmp =(1st record) W:\Foldername\Micromap Run 001 B.bmp =(1st record) W:\Foldername\Micromap Run 002 A.bmp =(2nd record) W:\Foldername\Micromap Run 002 B.bmp =(2nd record) W:\Foldername\Micromap Run 003 A.bmp =(3rd record) W:\Foldername\Micromap Run 003 B.bmp =(3rd record) and so on... Image A goes to field A Image B goes to field B Is there a way of doing this au...

can't uninstall exchange from cluster nodes
hi our client has several exchange clusters, and one of them is being retired. we have removed the exchange resources and the EVS and the server no longer appears in the organization and everything else there seems to be ok. we can't seem to uninstall exchange from either of the nodes. setup will start saying it's loading components then terminates with no error; happens on both nodes. both nodes are exchange 2003 sp1 on windows 2003. i did find the setup log; here is what it says, hope someone can shed some light on this (company info replaced with < >): [19:47:23] *...

Formatting does not follow when copying from one cell to another
I have a cell on sheet 1 that I have added text to with some bolding, coloring of text, etc. On Sheet 2 I have a cell that I have told to copy whatever is in the cell on sheet 1 described above. Why doesn't the formatting copy over too?? A formula returns a result, not any formatting. Pete On Apr 7, 9:55=A0pm, Banker <Ban...@discussions.microsoft.com> wrote: > I have a cell on sheet 1 that I have added text to with some bolding, > coloring of text, etc. On Sheet 2 I have a cell that I have told to copy > whatever is in the cell on sheet 1 described above. =...

Can't delete email #2
I'm am trying to help a friend who is using Outlook Express on W98, I cannot delete any messages from her in box. She has over 500 in there, which may be part of the problem. Any suggestions? Desperate! Mark Mark Ryan <m.ryan@earthlink.com> wrote: > I'm am trying to help a friend who is using Outlook Express > on W98, I cannot delete any messages from her in box. She > has over 500 in there, which may be part of the problem. > Any suggestions? The first suggestion is to ask in an Outlok Express newsgroup. The second suggestion is to delete Deleted Items.dbx and ...

Can Not Reply To Emails
Running Windows 7 Professional with latest version of WLM. I get email messages I can not reply to. The reply button is grayed out. For now I am forwarding them to my WinXP computer and then replying from that computer with OE6. Anybody have any ideas? -- <Bill> Brought to you from Anchorage, Alaska. The most obvious reason for not having an active Reply button is not having a mail account set up. --=20 Gary VanderMolen, Microsoft MVP (Mail) http://mvp.support.microsoft.com/default.aspx/profile/vandermolen "Bill Bradshaw" <bradshaw@gci.net>...

How can I rename a database table?
Hi I am working on a project that uses the MFC CDatabase and CRecordset classes to handle its interfacing with an Access database. It is necessary for the software to rename a table within existing user databases to ensure that they are valid for use with the new version of the software. As a result of my limited database and MFC knowledge I am having difficulty finding a way of renaming the table. I have tried using the following: try { theDataBase.ExecuteSQL( "RENAME oldTableName TO newTableName"); } catch( CDBException* e) { e->m_strError; } However, it results in th...

how can I restore unsaved changes in excel #2
...

Can (or how can) I do this
Hello, My Access application tracks an employee's progress through a process similar to hiring. There are 5 steps in the process. I track 4 of the steps by counting the number of times a value appears in a date field for that step. The count is then displayed and used in a calculation. The 5th step is more complicated. The 5th step needs to determine if the employee has verified that he can access all the applications that he should have access to. My process tracking table has the first 4 dates. The application access info comes from a different table. This process trackin...

Can Not Connect to Exchange Server after Mailbox Move
I have 2 exchange servers. While logged into the domain, and at the location, I can log into the email system just fine. While remote VPN in, I can not access the server. I can ping the server, I can see all shares, and I can even access the printer and print from the exchange server. But I can not get to it with email. Any Ideas? Oh.. both exchange 5.5, both in the same site. Exchange Admin shows both sites just fine. is there a firewall with rules configured, in between the users vpn connection and the internal network? kmelillo@gmail.com wrote: > Oh.. both exchange 5.5, bot...

Can not archive
I get the message "Error while archiving folder "Deleted Items" in store "mailbox-user name." Some items could not be copied. They were either moved or deleted, or access was denied. This only happend recently and only occurs with the deleted items. I can archive send and the inbox without a problem. Any suggestions? Thanks ...

can'not set or connect to an email account
This is a multi-part message in MIME format. ------=_NextPart_000_0010_01CAAC2C.BBDF6A00 Content-Type: multipart/alternative; boundary="----=_NextPart_001_0011_01CAAC2C.BBDF9110" ------=_NextPart_001_0011_01CAAC2C.BBDF9110 Content-Type: text/plain; charset="Windows-1252" Content-Transfer-Encoding: quoted-printable I am triying to set an email account.I am vodafone mobile customer.Some = settings bloking my access to email service.I am not a professinal = computer user,following the the instractions but no luck.Can you help = me? Thank you. ------=_Nex...

Where can I download this type of db example?
Hi, I'm working in Access 2003. Where can I download a (free) Access database example that shows how to implement forms and queries for tables that break down many-to-many relationships with a link table? I understand normalization and I believe my structure is 3rd order normalized. I need to figure out how to input data into the tables and have them linked together automatically by a query (or, if necessary, VB code). In other words, a database that has tblParents (1->oo) tblParent_Child_LINK (1->oo) tblChildren where (1->oo) means One-to-many, if it wasn't c...

Can you convert picture into Visio?
Is there a way to convert picture into Visio format? If so, how? It would depend on what format the picture was in. For most cases, this is not an easy task. John... Visio MVP "tbae" wrote: > Is there a way to convert picture into Visio format? If so, how? ...