find formula and return value

Hi i am using the following formula to find text in a cell 
=IF(ISNUMBER(FIND("Super",B96)),"OK", "Not OK") and return a value. i have 
adapted the formula for another spreadsheet and simply added more values to 
check, i.e. =IF(ISNUMBER(FIND("Super""Account""Business:,B96)),"OK", "Not 
OK") but it doesnt seem to work. where i can see the value in the cell it is 
not returning ok instead of not ok. is there a limit to the number of values 
i can search and if so why doesnt it say as an error? what am i missing?
Thanks very much
0
5/2/2005 5:14:01 AM
excel.misc 78881 articles. 5 followers. Follow

5 Replies
497 Views

Similar Articles

[PageSpeed] 7

The find fuction will only let you search for a single string so you will 
need to adapt your formula to something like:

=IF(OR(ISNUMBER(FIND("Super",B96)),ISNUMBER(FIND("Account",B96)),ISNUMBER(FIND("Business",B96))),"OK","Not OK")

(watch out for the line wrap)

Hope this helps
Rowan

"Micayla Bergen" wrote:

> Hi i am using the following formula to find text in a cell 
> =IF(ISNUMBER(FIND("Super",B96)),"OK", "Not OK") and return a value. i have 
> adapted the formula for another spreadsheet and simply added more values to 
> check, i.e. =IF(ISNUMBER(FIND("Super""Account""Business:,B96)),"OK", "Not 
> OK") but it doesnt seem to work. where i can see the value in the cell it is 
> not returning ok instead of not ok. is there a limit to the number of values 
> i can search and if so why doesnt it say as an error? what am i missing?
> Thanks very much
0
Rowan (114)
5/2/2005 5:52:04 AM
Try

=IF(OR(ISNUMBER(FIND({"Super","Account","Business"},B96))),"OK", "Not OK")

-- 
Regards,

Peo Sjoblom


"Micayla Bergen" <MicaylaBergen@discussions.microsoft.com> wrote in message 
news:E2A52114-40B3-46A6-A929-7EDF2A811420@microsoft.com...
> Hi i am using the following formula to find text in a cell
> =IF(ISNUMBER(FIND("Super",B96)),"OK", "Not OK") and return a value. i have
> adapted the formula for another spreadsheet and simply added more values 
> to
> check, i.e. =IF(ISNUMBER(FIND("Super""Account""Business:,B96)),"OK", "Not
> OK") but it doesnt seem to work. where i can see the value in the cell it 
> is
> not returning ok instead of not ok. is there a limit to the number of 
> values
> i can search and if so why doesnt it say as an error? what am i missing?
> Thanks very much 

0
terre081 (3244)
5/2/2005 5:57:32 AM
Hi!

Make a list of the words you want to find:

A1 = Super
A2 = Account
A3 = Business

=IF(SUMPRODUCT(--(ISNUMBER(FIND(A1:A3,B96)))),"Ok","Not Ok")

Tips:

FIND is case sensitive, SEARCH is not:

=IF(SUMPRODUCT(--(ISNUMBER(SEARCH(A1:A3,B96)))),"Ok","Not Ok")

Both FIND and SEACH will fail in situations when these types of values are 
being tested:

Super = Superstitious = Superbowl

Account = Accountant

You can make the formula a little more robust by looking for the words with 
a space on either side:

=IF(SUMPRODUCT(--(ISNUMBER(SEARCH(" "&A1:A3&" "," "&B96&" ")))),"Ok","Not 
Ok")

This will help reduce false positives in that:

Super <> Superstitious <> Superbowl

Even using the above formula, it's still not 100% foolproof.

Biff

"Micayla Bergen" <MicaylaBergen@discussions.microsoft.com> wrote in message 
news:E2A52114-40B3-46A6-A929-7EDF2A811420@microsoft.com...
> Hi i am using the following formula to find text in a cell
> =IF(ISNUMBER(FIND("Super",B96)),"OK", "Not OK") and return a value. i have
> adapted the formula for another spreadsheet and simply added more values 
> to
> check, i.e. =IF(ISNUMBER(FIND("Super""Account""Business:,B96)),"OK", "Not
> OK") but it doesnt seem to work. where i can see the value in the cell it 
> is
> not returning ok instead of not ok. is there a limit to the number of 
> values
> i can search and if so why doesnt it say as an error? what am i missing?
> Thanks very much 


0
biffinpitt (3171)
5/2/2005 6:13:29 AM
Thanks very much, it worked like a dream - albeit a convoluted and 
long-winded one!

"Rowan" wrote:

> The find fuction will only let you search for a single string so you will 
> need to adapt your formula to something like:
> 
> =IF(OR(ISNUMBER(FIND("Super",B96)),ISNUMBER(FIND("Account",B96)),ISNUMBER(FIND("Business",B96))),"OK","Not OK")
> 
> (watch out for the line wrap)
> 
> Hope this helps
> Rowan
> 
> "Micayla Bergen" wrote:
> 
> > Hi i am using the following formula to find text in a cell 
> > =IF(ISNUMBER(FIND("Super",B96)),"OK", "Not OK") and return a value. i have 
> > adapted the formula for another spreadsheet and simply added more values to 
> > check, i.e. =IF(ISNUMBER(FIND("Super""Account""Business:,B96)),"OK", "Not 
> > OK") but it doesnt seem to work. where i can see the value in the cell it is 
> > not returning ok instead of not ok. is there a limit to the number of values 
> > i can search and if so why doesnt it say as an error? what am i missing?
> > Thanks very much
0
5/2/2005 6:36:16 AM
Sp why didn't you try my formula?

-- 
Regards,

Peo Sjoblom


"Micayla Bergen" <MicaylaBergen@discussions.microsoft.com> wrote in message 
news:E7309059-FBDF-447D-868C-05382EDF7A13@microsoft.com...
> Thanks very much, it worked like a dream - albeit a convoluted and
> long-winded one!
>
> "Rowan" wrote:
>
>> The find fuction will only let you search for a single string so you will
>> need to adapt your formula to something like:
>>
>> =IF(OR(ISNUMBER(FIND("Super",B96)),ISNUMBER(FIND("Account",B96)),ISNUMBER(FIND("Business",B96))),"OK","Not 
>> OK")
>>
>> (watch out for the line wrap)
>>
>> Hope this helps
>> Rowan
>>
>> "Micayla Bergen" wrote:
>>
>> > Hi i am using the following formula to find text in a cell
>> > =IF(ISNUMBER(FIND("Super",B96)),"OK", "Not OK") and return a value. i 
>> > have
>> > adapted the formula for another spreadsheet and simply added more 
>> > values to
>> > check, i.e. =IF(ISNUMBER(FIND("Super""Account""Business:,B96)),"OK", 
>> > "Not
>> > OK") but it doesnt seem to work. where i can see the value in the cell 
>> > it is
>> > not returning ok instead of not ok. is there a limit to the number of 
>> > values
>> > i can search and if so why doesnt it say as an error? what am i 
>> > missing?
>> > Thanks very much 

0
terre081 (3244)
5/2/2005 1:52:49 PM
Reply:

Similar Artilces:

I need to compare 3 numbers and find the one in the middle
I have three numbers in a single row and would like to identify the middle number enter that number in another cell. Example: 1st # 2nd # 3rd # result 628 678 720 678 655 625 700 655 748 720 725 725 is there a function in excel that can do this? Thanks, Eddie Try =LARGE(A1:C1,2) VBA Noo -- VBA Noo ----------------------------------------------------------------------- VBA Noob's Profile: http://www.excelforum.com/member.php?action=getinfo&userid=3383 View this thread: http://www.excelforum.com/showthread.php?threadid=56811 fasteddie wrote.....

Find Duplicate names and delate
Dear experts, I have a small doubt could you clarify that??? That is I find duplicate name but I want to delete one name only, if I filter DUPLICATE….. both names are showing… 1. Select the range of data including the header. You need to have headers for these columns 2. From menu Data>Filter>Advanced Filter>Copy to another location 3. In 'copy to' specify the target cell and check 'Unique records only' 4. Click OK will give you the unique list -- Jacob "Find Duplicate names and delate" wrote: > Dear experts, > I have a small ...

Finding a Median
I'm trying to write a query that will return a median for various values taken from a previous query. I've seen some suggestions in my searching, but I haven't been able to get them working. They are also all from before 2003 and refer to Access 97 and 2000. Has any functionality been added to 2003 for this? Or is there a non- code-based way to do it? I've seen it suggested to write a code to open the query, sort it, find the total number of records, divide it in half, then seek out the middle record using that value. I'm still very green when it comes to code, though...

Find a Value the first Time It Occurs
I have a row of values that shows the total cumulative number of sales of items by month. Occasionally, there may be no sales in a month for an item so the cumulative value would stay the same for more than one month. I want to select a number in the row the first time it occurs and not select it if it repeats. What are you wanting to do with the info? To return position (column number) of number 1234 within row 2: =MATCH(1234,2:2,0) A formula that signals it's the first occurence: =COUNTIF($A2:A2,A2)=1 This could be used in a helper row, or as a conditional format f...

how do I delete numbers without deleting formulas
In excel 2003 how do I delete a column of numbers without deleting the formulas in the column? F5>Special>Constants. Use the option buttons to select what you wish to highlight for deleting>Ok Edit>Clear Contents. Gord Dibben Excel MVP On Sat, 8 Oct 2005 13:13:02 -0700, "Emmaus junkie" <Emmaus junkie@discussions.microsoft.com> wrote: >In excel 2003 how do I delete a column of numbers without deleting the >formulas in the column? ...

Easy Formula?
I Have A Column A & B I Have A Formula At Column C =sum(a2*b2)+(a3*b3)+(a4*b4) Answer Is 31 I Want To Multiply A1 And B1 Up To The Last Range Of Data Add The Total Product The Problem Is: If Have A Lot Of Data In Column A & B, The Formula Is So Very Long Theres Any Easy Formula? A B 3 5 2 7 2 2 -- xtrmhyper ------------------------------------------------------------------------ xtrmhyper's Profile: http://www.excelforum.com/member.php?action=getinfo&userid=23851 View this thread: http://www.excelforum.com/showthread.php?threadid=3908...

Find/Replace in RichEdit 2.0
I'm using Windows ME and I've switched from RichEdit 1.0 to 2.0 for my CRichEditDoc/View application so that I can use the ITextDocument interface and can do things such as suspend/resume the Redo buffer. Problem is, now the Find/Replace dialogs don't seem to do anything. If I revert back to RichEdit 1.0 they do! What's going on? BUMP! adriangibbons@yahoo.co.uk (Adrian Gibbons) wrote in message news:<34a2acd5.0404130713.123dbaab@posting.google.com>... > I'm using Windows ME and I've switched from RichEdit 1.0 to 2.0 for my > CRichEditDoc/View application...

Find (but not find)
My program takes a name from sheet3 goes to sheet1 to Find the name. If it cannot find name, how do you do an If/End to Exit Do while or find out if name has been founf? I have "On Error Resume Next" in program. Thanks again for all your help Gordon As ALWAYS, post your code for comments & suggestions. -- Don Guillett Microsoft MVP Excel SalesAid Software dguillett1@austin.rr.com "Gordon" <gwelch1938@yahoo.com> wrote in message news:1184612089.486737.144020@n60g2000hse.googlegroups.com... > My program takes a name from sheet3 goes to sheet1 to Find the na...

is there a comand to return the mane of a worksheet inside a cell
Trying to find a command that returns a worksheet name inside a cell Hi Fabian Try this, =MID(CELL("filename"),FIND("[",CELL("filename"))+1,FIND("]",CELL("filename"))-FIND("[",CELL("filename"))-1) This one will give you the full path: =CELL("filename") HTH John "Fabian" <Fabian@discussions.microsoft.com> wrote in message news:140C847D-2C3A-49F6-9C60-9515B426AD5E@microsoft.com... > Trying to find a command that returns a worksheet name inside a cell Hi, =MID(CELL("filename...

Finding an event
Hello, I am developing an app that uses a single worksheet to enter data. When user double clicks a button, a new window (in same workbook) opens with a new sheet. My problem is that excel does not seem to have any events for close of window if there are multiple windows in a workbook. Can someone help Peter Peter, That triggers the Workbook_WindowActivate event, you can use that. HTH Bob "Peter Ostermann" wrote in message news:i9m5v8$7bv$02$1@news.t-online.com... Hello, I am developing an app that uses a single worksheet to enter data. When user double clicks a button...

Microsoft Money 2004
I just upgraded from Money 2002 to Money 2004. Can somebody please explain why I just paid AUD$80 for THE SAME SOFTWARE? Very, very disapointed. What information did you rely on to set your value expectation level that M04 was way different, indeed AUD$80 better, than M02? That might help explain it better than we can. "Paul Ward" <pbward@hotmail.com> wrote in message news:04b401c35bb8$b9fea7d0$a501280a@phx.gbl... > I just upgraded from Money 2002 to Money 2004. Can > somebody please explain why I just paid AUD$80 for THE > SAME SOFTWARE? > > Very, very disa...

Find value in a column and insert rows above
The set up looks like this: ColU ColV ColW ColX Y N N N Y N N N N Y N N N N Y N N N Y N N N Y N N N Y N N N Y Y Columns will always be U through X and will always be sorted in this order. I need to find the first Y in each column and insert 2 rows above that row. On the blank row above the first Y, I need to highlight in yellow and put title in the first cell, such as New, Old, Existing, Deleted. Any help would be greatly appreciated. Thanks for your time, Dee If desired, send your file to my address below. I will only look if: 1. You send a copy of this ...

Formula
Hi all, I am preparing an exam marksheet. In one cell, I add in this formula to check if a student pass or fail the whole exam. Condition ... the students must not get any "E" to pass the whole exam. =IF(OR(E7="E",G7="E",I7="E",K7="E",M7="E",O7="E",Q7="E",S7="E",U7="E",W7="E" ,Y7 ="E",AA7="E",AC7="E",AE7="E"),"Fail","Pass")) Now I want to change to another condition. The students must not get any "E", or "D&...

Sum if Condition is Equal in Range Date and find column
I want to make a sum if Range is a week number and if style is Equal to CONC-92 or CONC-45 Week# 49 Week# 50 CONC-92= 27 CONC-92= 30 CONC-45= 27 CONC-45= 30 Datas are in a pivot table and... Pivot table looks like this: Date CONC-92 CONC-45 CONC-92 CONC-45 12/7 5 5 10 10 12/8 2 2 10 10 12/9 5 5 10 10 12/10 5 5 10 10 please help -- Lorenzo Díaz Cad Technician ...

Simple division is not returning actual value
Hi, I know I'm making a mistake somewhere, just not sure where. I'm dividing 67/14 and want to get the result as 4.78 -- I'd be OK with 4.79 which is the result I'd get if the last digit was rounded up. When I do SELECT CAST((67/14) AS DECIMAL(3,2)) I'm getting 4.00. What am I doing wrong? -- Thanks, Sam This is because of integer division. Try this: SELECT 67/CAST(14 AS DECIMAL(5,2)) AS a, 67/14.0 AS b, 1.0 * 67/14 AS c, CAST(1.0 * 67/14 AS DECIMAL(3, 2)) AS d, ROUND(1.0 * 67/14, 2, 1) AS e; /* a b...

cannot find database
I have an excel spreadsheet that is supposed to update a access db. Whenever I try to save the .xls I get an error stating cannot find db. Even when I open the db with access, I get the error and the db opens anyway?????? This only happens on 2 out of 20 pc's and I cannot figure out why???????? Thanks ...

Subform comparison of 2 tables excluding non zero value
I am creating a subform (at least that is what I am assuming would be best choice)(Access 2003/NT) in which the user will type in a Melt# (contained in the tblChemicalResults). I need to create a side by side comparison of the chemical requirements from the tblChemicalRequirements to the actual results contained in the tblChemicalResults, but I need it to exclude any non zero values from both tables. Each table contains all of the possible 14 different metal elements that could possibly go into making a particular part. Obviously, not all 14 go into every part, so how do I display only ...

FORMULAS please help
Hi there I am trying to create a formula that refences <> numbers in a columm then adds up the from a different columm i.e add b1:b100 only if a1:a100 is >10000 <12000 =46 a b 10000 32 9000 64 12001 86 11999 14 9990 12 One way =SUMPRODUCT(--(A1:A100>10000),--(A1:A10000<12000),B1:B10000) Regards, Peo sjoblom boogie wrote: > Hi there > I am trying to create a formula that refences <> numbers in a columm then > adds up the from a different columm > i.e add b1:b1...

Copying Formulas to rows
Hi All, I have created a book which has various formulas accross a row which are all worked out from figures in that row. But I cant figure how to make the whole sheet use these forumlas, i.e. when i start typing info on row 2 it uses the same formulas as on row 1. The only way I have worked out so far to do this is to copy and paste each row, but this is time consuming and im sure there must be a quicker way? Thanks in advance for your help. -- mdj101 ------------------------------------------------------------------------ mdj101's Profile: http://www.excelforum.com/member.php?a...

Format only parts of a formula result?
I created a formula composed mostly of text, including a small formula. This formula: ="The products would be $"&ROUND(E28/1000,0)&"K but since new revenues are enabled almost instantly," is intended to produce: The products would be $1335K but since new revenues are enabled almost instantly, Is there a way to BOLD or ITALICIZE the "$1335K" result but leave the other text unbolded? Scott -- sdubose99 ------------------------------------------------------------------------ sdubose99's Profile: http://www.excelforum.com/member.php?action...

Excel - Array Formulas - Freeze
Hi all I have a big problem. It takes about 30 minutes to save my excel fil because I have many array formula: about 32 000! So do you have a ti to accelerate the computing process? Is a VBA function would do i faster? Here is an example of what I use: Col A contain unique numbers Sheet 1: Col A Col B Col C Row1 001 123 9i9 Row2 005 456 8u8 Row3 003 406 8ur etc... to +8000 In sheet 2, I have to check if the data exist in sheet 1. Col D contai Yes (data is in the sheet1) or No... Examples: Col D check if the data in Col B is the same in sheet 1 Col...

Requesting Help Ranking Sales Values.....
I have a field in a table named "Ext B/O" that lists the extended Backorder Value for parts sold. There may be duplicate values and they should show the same rankings. I would like to rank these totals from highest to lowest dollar value. I have tried the following query coding but I only get a count of the total number of records in the query for each record (49435) and NOT the individual ranking of the value. Rank: (Select Count(*) from [tbl_WorkingData] Where [Ext B/O] >= 0)+1 Can ANYONE please tell me what I am doing wrong and how to correct it? Th...

Trapping a NO FIND after a find
I use the code below to store a row number to a variable after a find. I would like to trap a NO FIND if the find is unsuccessfull Any ideas. FSt1 provided the code below Sub macfindrow() dim rn as string dim rng as range dim therow as long rn = inputbox("enter something to find") if rn <> "" then Set rng = nothing Set rng = range("A1:IV65536").Find(what:=rn, _ After:=Range("A1"), _ Lookin:=xlformulas, _ Lookat:=xlpart, _ ...

Please help
I have a query that returns text. SOME text is just text but some text has a number like X1027 - in front of the text. It might read like "X1027 - Jonesboro High School". The text lengths vary from school to school and some don't have the numbers in front. How can I remove the numbers, spaces, and - in front of the ones that do and leave alone the ones that don't. Help!!! Thanks so much!!!!!! "Golfinray" <Golfinray@discussions.microsoft.com> wrote in message news:93B7A4A5-7287-409C-AA89-200820C8DF5A@microsoft.com... >I have a query that returns text....

ignoring text data in a cell when summing values in the same cell
I have entered text in cells along with a numerical value as a note pertainig to the values example, "2 - exist". Is there a way to tell Excell to ignore the text data in order to sum the values..do you place the text in brackets or parathesis or something similar? -- FM Much, much easier never to mix text & numbers in the same cell in the 1st place. One avenue here, try use Data>Text to Columns to split the numbers separate from the text, then you can sum (or whatever) the numbers col directly. Or, assuming your data is representative (ie numbers are to the...